ClearAll["Global`*"];

Here are shortcuts that define the Fourier transform and Inverse transform according to the convention in the textbook:

FT[f_,x_,k_]:=FourierTransform[f,x,k,FourierParameters->{0,-1}]

IFT[ff_,k_,x_]:=InverseFourierTransform[ff,k,x,FourierParameters->{0,-1}]

It would be reassuring to verify that these definitions are self-consistent in the sense that the inverse transform of a transformed function is itself, and vice versa. Let’s show this for two specific functions: f(x)=(e^(-a (x^2)/2)) and g(x) = sinc(a x) = sin(a x)/a x.

f[x_] := Exp[-(a/2)x^2]

ff[k_] := FT[f[x],x,k]

f[x]//TraditionalForm

ff[k]//TraditionalForm

Assuming[a>0,IFT[FT[f[x],x,k],k,x]]//TraditionalForm

Assuming[a>0,FT[IFT[ff[k],k,x],x,k]]//TraditionalForm

It is true that the gaussian maps back to itself.

Assuming[a>0,IFT[FT[f[x],x,k],k,x]]==f[x]

Assuming[a>0,FT[IFT[ff[k],k,x],x,k]]==ff[k]

g[x_]:=Sinc[a x]

gg[k_]:=FT[g[x],x,k]

g[x]//TraditionalForm

gg[k]//TraditionalForm

Assuming[a>0,IFT[FT[g[x],x,k],k,x]]//TraditionalForm

Assuming[a>0,FT[IFT[gg[k],k,x],x,k]]//TraditionalForm

It is also true that the sinc function maps back to itself.

Assuming[a>0,IFT[FT[g[x],x,k],k,x]]==g[x]

Assuming[a>0,FT[IFT[gg[k],k,x],x,k]]==gg[k]

Now let’s consider the rule that governs translations. It says that shifts of the argument in x-space show up a multiplicative phase factor in k-space: (F^(-1))[(OverTilde[f])(k)](x-(Subscript[x, 0])) = (F^(-1))[(e^(-i k (Subscript[x, 0])))(OverTilde[f])(k)](x).

f[x]//TraditionalForm

Assuming[a>0,IFT[ff[k],k,x]]//TraditionalForm

f[x-x0]//TraditionalForm

Assuming[a>0,IFT[Exp[-I k x0] ff[k],k,x]]//TraditionalForm

Assuming[a>0,IFT[Exp[-I k x0] gg[k],k,x]]//TraditionalForm

The Fourier transform is linear.

FT[a f[x] + b g[x],x,k]

% == a ff[k] + b gg[k]

We can demonstrate the differentiation rule, which says that f'(x) = (F^(-1))[i k (OverTilde[f(k)])], f''(x) = (F^(-1))[(((i k))^2) (OverTilde[f(k)])], ... , (f^((n)))(x) = (F^(-1))[(((i k))^n) (OverTilde[f(k)])].

Assuming[a>0,IFT[I k ff[k],k,x]]//TraditionalForm

%==f'[x]

Assuming[a>0,IFT[(I k)^2 ff[k],k,x]]//TraditionalForm

Expand[%]==f''[x]

Assuming[a>0,IFT[(I k)^3 ff[k],k,x]]//TraditionalForm

Expand[%]==f'''[x]

Assuming[a>0,IFT[I k gg[k],k,x]]//TraditionalForm

Expand[%]==Expand[g'[x]]

Assuming[a>0,IFT[(I k)^2 gg[k],k,x]]//TraditionalForm

Expand[%]==Expand[g''[x]]

Assuming[a>0,IFT[(I k)^3 gg[k],k,x]]//TraditionalForm

Expand[%]==Expand[g'''[x]]

Convolve[f[y],f[y],y,x]/Sqrt[2π]//TraditionalForm

Simplify[Assuming[a>0,Integrate[f[y]*f[x-y],{y,-∞,∞}]/Sqrt[2π]]]//TraditionalForm

Assuming[a>0,IFT[ff[k]^2,k,x]]//TraditionalForm

Convolve[f[y],g[y],y,x]/Sqrt[2π]//TraditionalForm

Simplify[Assuming[a>0,Integrate[g[y]*f[x-y],{y,-∞,∞}]/Sqrt[2π]]]//TraditionalForm

Assuming[a>0,IFT[ff[k]gg[k],k,x]]//TraditionalForm

u[x_]:= HeavisideTheta[x]*Exp[-a x]

v[x_]:=Sin[b x]

uu[k_]:=FT[u[x],x,k]

uu[k]//TraditionalForm

vv[k_]:=FT[v[x],x,k]

vv[k]//TraditionalForm

Simplify[uu[k] vv[k]]//TraditionalForm

Simplify[Assuming[a>0&&b>0,IFT[uu[k] vv[k],k,x]]]//TraditionalForm

Convolve[u[y],v[y],y,x]/Sqrt[2π]//TraditionalForm