Solutions to PHYS729, homework #04.

Problem 3.4

Here we study the paraboloidal coordinate system

Quit[];

Compute the transformation matrices and construct the metric

Quit[];
$Assumptions={Element[{u,v,ϕ,x,y,z},Reals]}

Define the two coordinates and the dimension of the manifold (3)

a={u,v,ϕ};
b={x,y,z};

x=u v Cos[ϕ];
y=u v Sin[ϕ];
z=(1/2) ((u^2)-(v^2));
dim=3;

Compute the transformation matrix. Make sure you understand the definition.

TransMatrix=ParallelTable[
D[b[[i]],a[[j]]]
,{i,1,dim},{j,1,dim}];
InvTransMatrix=FullSimplify[Inverse[TransMatrix]];

TransMatrix//MatrixForm

InvTransMatrix//MatrixForm

Check that the result makes sense

TransMatrix.InvTransMatrix//FullSimplify//MatrixForm

det=Det[TransMatrix]//FullSimplify

Singular points are u = 0 and v = 0.

gdd=Transpose[TransMatrix].(IdentityMatrix[3].TransMatrix)//FullSimplify;
guu=Inverse[gdd]//FullSimplify;

gdd//MatrixForm
guu//MatrixForm

Compute the determinant of the metric

detg=Det[gdd];
detg=Sqrt[-detg]//FullSimplify;
Do[g[i,j]=Simplify[gdd[[i,j]]];,{i,1,dim},{j,1,dim}];

Compute the elements of the Christoffel symbol

Compute the Christoffel symbols. Make sure you can read the line below.

Christoffel=ParallelTable[Sum[(1/2) guu[[k,l]] (D[gdd[[l,i]],x[[j]]]+D[g[l,j],x[[i]]]-D[g[j,i],x[[l]]]),
{l,1,dim}],
{k,1,dim},
{j,1,dim},
{i,1,dim}];

Displaying the non-zero Christoffel symbols Γ^{k}_{ij}, where u = 1, v = 2 and ϕ = 3 :

Do[If[UnsameQ[Christoffel[[k,j,i]],0],Print[Γ[k,j,i]," = ",Christoffel[[k,j,i]]]],{k,1,dim},{j,1,dim},{i,1,dim}]

Compute the divergence and laplacian

Define a vector V = V(u,v,ϕ) as and compute it’s divergence using the defintion.

V={Vu[u,v,ϕ],Vv[u,v,ϕ],Vϕ[u,v,ϕ]};

divV=Sum[D[V[[i]],a[[i]]],{i,1,dim}]+Sum[Christoffel[[j,j,i]] V[[i]],{i,1,dim},{j,1,dim}]//FullSimplify

Compute the laplacian of a scalar function Φ = Φ(u, v, ϕ)

LaplV=(1/detg) Sum[D[detg guu[[i,j]] D[Φ[u,v,ϕ],a[[j]]],a[[i]]],{i,1,dim},{j,1,dim}];

Simplify the expression a little

Collect[LaplV,{(1/((u^2) (v^2))),(1/((((u^2)+(v^2)))^2))},Simplify]

Problem 3.7

Here we study and compute some geometrical quantities for a 3-sphere manifold.

Quit[];

Define the metric and compute its determinant and inverse.

x={ψ,θ,ϕ};

gdd={{g11,0,0},
{0,g22,0},
{0,0,g33}};
g11=1;
g22=((Sin[ψ])^2);
g33=((Sin[ψ])^2) ((Sin[θ])^2);

guu=Inverse[gdd];
dim=Length[gdd];
detg=Det[gdd];
detg=Sqrt[-detg]//FullSimplify;
Do[g[i,j]=Simplify[gdd[[i,j]]];,{i,1,dim},{j,1,dim}];

Compute various geometric objects

Below we calculate, in the following order, the: Christoffel symbols Γ^{i}_{jk}, Riemann tensor R^{k}_{jia}, the Ricci tensor Ricci_{ja} = R^{k}_{jka}, the Ricci scalar RicSca = g^{ja} R_{ja} and the Einstein tensor Eins_{ja} = Ricci_{ja} - (1/2)*g_{ja}RicSca. 

Make sure you understand the definitions below! Note that we also compute other things such as the Kretschmann scalar a curvature scalar contructed from the full contraction of the Riemann tensor with itself.

Christoffel=ParallelTable[Sum[(1/2) guu[[k,l]] (D[gdd[[l,i]],x[[j]]]+D[g[l,j],x[[i]]]-D[g[j,i],x[[l]]]),
{l,1,dim}],
{k,1,dim},
{j,1,dim},
{i,1,dim}];

Riemannuddd=ParallelTable[
FullSimplify[
D[Christoffel[[a,i,k]],x[[j]]]-D[Christoffel[[a,j,i]],x[[k]]]+
Sum[
Christoffel[[a,j,β]]Christoffel[[β,k,i]]-Christoffel[[a,k,β]]Christoffel[[β,j,i]],
{β,1,dim}]]
,
{a,1,dim},
{i,1,dim},
{j,1,dim},
{k,1,dim}];

Ricci=ParallelTable[
FullSimplify[
Sum[Riemannuddd[[l,j,l,a]],{l,1,dim}]],
{j,1,dim},
{a,1,dim}
];

RicSca=Simplify[Sum[guu[[j,a]] Ricci[[j,a]],
{j,1,dim},
{a,1,dim}]];

Einstein=ParallelTable[
Simplify[Ricci[[j,a]]-(1/2)RicSca g[j,a]],
{j,1,dim},
{a,1,dim}];

Riemanndddd=ParallelTable[
Sum[gdd[[i,α]] Riemannuddd[[α,j,k,l]],{α,1,dim}],
{i,1,dim},
{j,1,dim},
{k,1,dim},
{l,1,dim}
];

Riemannuuuu=ParallelTable[
Sum[guu[[γ,k]] guu[[β,j]] guu[[α,i]] Riemannuddd[[a,α,β,γ]],{α,1,dim},
{β,1,dim},
{γ,1,dim}],
{a,1,dim},
{i,1,dim},
{j,1,dim},
{k,1,dim}
];

Kretschmann=Sum[
Riemanndddd[[α,β,γ,δ]] Riemannuuuu[[α,β,γ,δ]],
{α,1,dim},
{β,1,dim},
{γ,1,dim},
{δ,1,dim}]//FullSimplify;

Ricciuu=ParallelTable[
Sum[guu[[i,l]] guu[[j,m]] Ricci[[l,m]],{l,1,dim},{m,1,dim}],
{i,1,dim},
{j,1,dim}]//FullSimplify;

Output the results:

Ricci scalar

RicSca

Displaying the non-zero Christoffel symbols Γ^{k}_{ij}, where ψ = 1, θ = 2 and ϕ = 3 :

Do[If[UnsameQ[Christoffel[[k,j,i]],0],Print[Γ[k,j,i]," = ",Christoffel[[k,j,i]]]],{k,1,dim},{j,1,dim},{i,1,dim}]

Dislaying the non-zero elements of the Riemann tensor R^{k}_{j i a}

Do[If[UnsameQ[Riemannuddd[[k,j,i,a]],0],Print[R[k,j,i,a]," = ",Riemannuddd[[k,j,i,a]]]],{k,1,dim},{j,1,dim},{i,1,dim},{a,1,dim}]

Displaying the non-zero elements of the Ricci tensor R_{i j}

Do[If[UnsameQ[Ricci[[j,a]],0],Print[Ric[j,a]," = ",Ricci[[j,a]]]],{j,1,dim},{a,1,dim}]

For fun, output the value of the Kretschmann scalar.

Kretschmann